Schlagwort-Archive: Feuchtsensor

Kapazitiver Regensensor Funktionsweise

Zum Blogbeitrag MQTT-Regensensor Modul

Allgemeines:

Im Internet wird eine Vielzahl von verschiedenen Regensensoren angeboten. Die meisten davon kommen aus Fernost und arbeiten nach dem Resistance Prinzip.

Trifft ein Regentropfen auf die nicht isolierten Kontakte des Sensors, werden die nebeneinanderliegenden kammförmigen Kontakte durch den Regen verbunden, was letztendlich zu einer Reduzierung des Sensorwiderstandes fĂŒhrt.

Diese WiderstandsÀnderung ist abhÀngig vom Verschmutzungsgrad des Regenwassers, sowie der bereits eingetretenen Oxidation des Regensensors.

Über eine Komparator Schaltung kann hierbei meist der Schaltpegel eingestellt werden, bei dem Regen detektiert wird und der dann ein digitales Ausgangssignal setzt.

Manche Sensoren stellen zusĂ€tzlich zu diesem Digitalausgang noch ein Analogsignal zur VerfĂŒgung, was eine Lösung fĂŒr eine zeitweilige Kalibrierung des Sensors durch die Software erlauben wĂŒrde.

Das große Problem bei dieser Messmethode ist es, dass selbst bei Sensoren mit vergoldeten KontaktoberflĂ€chen immer parasitĂ€re Ströme fließen.

Da praktisch immer ein kleiner Gleichstrom an beiden Polen des Sensors anliegt, fĂŒhrt dies unabhĂ€ngig von der QualitĂ€t des Sensors zu einem elektrochemischen Prozess und damit ĂŒber kurz oder lang zu einer schrittweisen Zerstörung des Sensors.

Eine bessere Lösung stellt dieser Sensor dar, da er auf einem anderen Prinzip, dem kapazitiven Prinzip beruht.

Das Funktionsprinzip bei einem kapazitiven Sensor ist dem oben vorgestellten Messverfahren durchaus Àhnlich. Es unterscheitet sich jedoch in einem wesentlichen Punkt, bei Regen wird hier keine leitende Verbindung hergestellt. Durch die Wassertropfen auf der OberflÀche wird lediglich die KapazitÀt des Sensors verÀndert, das Wasser wirkt als Dielektrikum.

Der Vorteil bei diesem Lösungsansatz liegt darin, dass keine blanken LeiterbahnoberflĂ€chen der Witterung ausgesetzt sind und dadurch auch kein elektrochemischer Prozess ausgelöst wird, der den Sensor auf Dauer irreversibel beschĂ€digt. Alle leitenden Teile sind durch eine Lackschutzschicht vor WitterungseinflĂŒssen geschĂŒtzt.

Die KapazitĂ€t des Sensors betrĂ€gt im trockenen Zustand ca. 170pF. Tritt eine Betauung ein oder trifft Regen auf den Sensor, steigt die KapazitĂ€t an. Durch das ermittelte Delta C, lĂ€sst sich sogar eine Aussage ĂŒber die Art des Regens und dessen IntensitĂ€t treffen. Ist es Neblig oder es handelt sich um einen feinen Nieselregen, der die SensoroberflĂ€che benetzt, bilden sich viele kleine Wasser Tröpfchen auf dem Sensor, was wiederrum zu einem großen Delta C fĂŒhrt.
Bei einem Durchschnittlichen Regen Ereignis sind es vorwiegend grĂ¶ĂŸere Tropfen, die zu einem großen Teil sofort wieder abrutschen, so ergibt sich ein kleineres Delta C.

Um schnell festzustellen zu können, ob der Regen zu Ende ist, besitzt der Sensor eine Heizung an der Platinen Unterseite. Diese besteht aus zwanzig 15 Ohm HeizwiderstÀnde, die es bei einer Versorgungsspannung von 5V immerhin auf eine Heizleistung von knapp 1,8 W bringen.
Sie sorgen fĂŒr eine zĂŒgiges verdunsten der FlĂŒssigkeit bzw. einer Eisbildung auf der SensoroberflĂ€che.

Durch die sehr kleine Bauform des Sensors, kann selbst mit dieser relativ geringen  Leistung ein schnelles (ca. 5 MinĂŒtiges) Abtrocknen sichergestellt werden.
Energetisch gesehen ist es sinnvoll, die Sensorheizung nur fĂŒr die Dauer einer Regenerkennung zu betreiben. Das bedeutet, wird keine Feuchtigkeit oder Regen mehr detektiert, soll die Sensorheizung abgeschaltet werden!
HierfĂŒr ist ein Transistor auf der Sensorplatine vorgesehen.
Wird hier ein Mosfet bestĂŒckt und ist der Pin in dieser Hardware Version 1.00 fĂŒr dessen Ansteuerung nicht angeschlossen, muss dieser auf Masse gelegt werden.
Da der Mosfet bei einem offenem Gate in einem Halbleitenden Zustand gehen könnte, was zur einer Zerstörung des Bauteils fĂŒhren wĂŒrde.

Diese Bild zeigt die BestĂŒckung der Unterseite des Sensors. Es ist gut zu erkennen, das im Layout zwar Pats fĂŒr eine Befestigung der Sensorplatine vorgesehen sind, diese jedoch keine Bohrung besitzen. Weshalb hier auch kurz auf die Befestigung des Sensors eingegangen werden soll.

Wie zu sehen ist befinden sich die AnschlĂŒsse annĂ€hernd mittig auf der Sensorplatine.

Verwandt man z.B. eine feste wasserdichte Hensel Anschlussdose um die Elektronik darin zu verstauen, genĂŒgt es in den Deckel ein passendes rundes Loch zu bohren, damit die AnschlĂŒsse nach innen geleitet werden können. Der Regensensor selbst wird am besten mit Silikon wasserdicht mit dem Deckel verklebt.
Sollten dennoch Befestigungslöcher benötigt werden, so können diese nachtrÀglich ausgebohrt werden.

Es bietet sich an die Platine fĂŒr die Auswertung mit dem entsprechenden GegenstĂŒck auszustatten, so dass diese von der Innenseite aufgesteckt werden kann.

Die Befestigung dieser Platine kann mit Distanzbolzen, die am Deckel eingeschraubt werden, erfolgen. Werden die Schrauben nicht vom Sensor (mit Silikon) ĂŒberdeckt, sollte hier auf Edelstahlschrauben zurĂŒckgegriffen werden.

Im Unteren Bild ist der Schaltplan der Sensorplatine zu sehen.
Bei der Steckverbindung wurde wert daraufgelegt, dass die Signale fĂŒr alle möglichen Anschlussvarianten an den Pins herausgefĂŒhrt wurden.

Somit stehen dem Endanwender auch alle möglichen Messverfahren zur VerfĂŒgung, die zur KapazitĂ€tsmessung angewandt werden können.

Kapazitiver Regensensor V1.01

Pin Belegung:

  1.  VDD +5V / 3,3V
  2. NC
  3. Sensorheizung
  4. Ladewiderstand
  5. Analog wert (Ladezustand)
  6. Entladewiderstand
  7. GND
  8. GND

KapazitÀtsmessung durch Laden- und Samplen der Kondensatorspannung

Die Platine des kapazitiven Regensensors wurde fĂŒr verschieden Anwendungsbereiche entwickelt, deshalb gibt es auch verschieden BestĂŒckungsvarianten.

Wenn man z.B. einen PIC Mikrokontroller mit einem Komperatoreingang verwnden, kann eine Messmethode angewendet werden, bei die KapazitĂ€t des Sensor ĂŒber den Pin 6, R23 entladen wird (Pin auf LOW) und der Pin anschließend wieder als Komperator Eingang umgeschaltet wird.
Der Pin 4, der zu diesem Zeipunkt im Tristate (hochohmig) war, wird nun als Ausgang programmiert und auf LOW geschaltet. Dieser lĂ€d nun die die KapazitĂ€t des Regensensors ĂŒber R22 auf, bis der Komperatoreingang kippt.
Die ermittelte Zeit dient dann als Grundlage fĂŒr die KapazitĂ€tsbestimmung.
Beim MQTT-Regensensormodul wird ein anderes Messvervahren angewannt, da dieser nicht ĂŒber einen Komperatoreingang verfĂŒgt.

Hier wird der AOUT (der gegen GND direkt die KapazitÀt des Sensors dartellt) als KapazitÀt eines Multivibrators genutzt, der abhÀngig von dieser KapazitÀt seine Ausgangsfrequenz Àndert. Diese Ausgangsfrequenz wird an einem digitalen Eingang des ESP8266 gemessen und die SensorkapazitÀt aus der Frequenz berrechnet.

Da fĂŒr dieses Messverfahren der C1, R22 und R23 nicht benötigt werden, mĂŒssen diese Bauteile bei diesem Messverfahren nicht mit bestĂŒckt werden.

Das obengenannte Messverfahren, dass sich jedoch nur fĂŒr grĂ¶ĂŸere KapazitĂ€ten im Bereich zwischen 10 nF und 2000 uF eigent, beschreibt der folgende Source Code von von Matthias Busse

Quellenverweis :
KapazitÀten von 10nF bis 2000uF einfach messen mit dem Arduino

// KapazitÀt MessgerÀt 10nF bis 2000uF
//
// Matthias Busse 22.2.2015 Version 1.1

#define messPin 0            // Analog Messeingang
#define ladePin 13           // Kondensator lade Pin ĂŒber einen 10kOhm Widerstand
#define entladePin 11        // Kondensator entlade Pin ĂŒber einen 220 Ohm Widerstand 
#define widerstand  9953.0F  // 10 kOhm > gemessen 9,953 kOhm

unsigned long startZeit;
unsigned long vergangeneZeit;
float microFarad;
float nanoFarad;

void setup() {
  pinMode(ladePin, OUTPUT);     // ladePin als Ausgang
  digitalWrite(ladePin, LOW);  
  Serial.begin(9600);           // Serielle Ausgabe
  Serial.println("Kapazitaetsmesser Version 1.1");
}

void loop() {
  // Kondensator laden
  digitalWrite(ladePin, HIGH);            // ladePin auf 5V, das Laden beginnt
  startZeit = micros();                   // Startzeit merken
  while(analogRead(messPin) < 648){}      // 647 ist 63.2% von 1023 (5V) 
  vergangeneZeit= micros() - startZeit - 114; // 0-Messung abziehen (112-116 us)
  if(vergangeneZeit > 4294960000) vergangeneZeit = 0; // Minuswerte auf 0 setzen (ist long deshalb der hohe Wert)
 // Umrechnung: us zu Sekunden ( 10^-6 ) und Farad zu mikroFarad ( 10^6 ),  netto 1  
  microFarad = ((float)vergangeneZeit / widerstand);   
  Serial.print(vergangeneZeit);           // Zeit ausgeben
  Serial.print(" nS    ");         

  if (microFarad > 1){
    if(microFarad < 100) {
      Serial.print(microFarad,2);         // uF.x ausgeben
      Serial.println(" uF     ");
    }
    else {
      Serial.print((long)microFarad);     // uF ausgeben
      Serial.println(" uF     ");
    }
  }
  else {
    nanoFarad = microFarad * 1000.0;     // in nF umrechnen
    if(nanoFarad > 10) {
      Serial.print((long)nanoFarad);     // nF ausgeben
      Serial.println(" nF     ");
      }
    else
      Serial.println("kleiner 10 nF");  
  }

  /* Kondensator entladen */
  digitalWrite(ladePin, LOW);             // ladePin auf 0V 
  pinMode(entladePin, OUTPUT);            // entladePin wird Ausgang 
  digitalWrite(entladePin, LOW);          // entladePin auf 0V 
  while(analogRead(messPin) > 0){}        // bis der Kondensator entladen ist (0V)
  pinMode(entladePin, INPUT);             // entladePin wird Eingang
  
  while((micros() - startZeit) < 500000){}   // bis 500ms warten, d.h. max 2 Ausgaben pro Sekunde
}

KapazitÀtsmessung sehr kleiner KapazitÀten

Da bei sehr kleien KapazitĂ€ten die Ladezeit des Kondensators ebenfalls sehr klein wird, mĂŒsste beim oben vorgestellten Messverfahren der Ladewiederstand im VerhĂ€ltnis hierzu entsprechend vergrĂ¶ĂŸert werden, um mit der Samplingrate des AD-Wandlers im Mikrokontroller immer noch ein akzeptables Messergebnis erzielen zu können.

Das Problem bei einem sehr großen Ladekondensator liegt darin, dass natĂŒrlich auch der analoge Eingang des Mikrokontrollers den Kondensator belastet und entlĂ€d. Der Messfehler wird also umso grĂ¶ĂŸer, je grĂ¶ĂŸer der Ladewiderstand wird, bis das System am Ende kippt und der Ladewiderstand die benötigte Ladung nicht mehr liefern kann.

Da sich die KapazitĂ€t des Regensensors in einem Bereich von 170pF – max. 400 pF bewegt, wird hier fĂŒr auf eine anderes Messverfahren zurĂŒckgegriffen werden.

Das Frequenzmessverfahren

Bei diesem Messverfahren wird keine ADC benötigt, es kommt mit einem Digitaleingang des Mikrokontrollers aus.
HierfĂŒr kommt der hochgenaue Langzeittimer NE555 zum Einsatz.
Dieser Timer seht sowohl in einer 5V Variante als NE555, als auch fĂŒr Mikrokontroller die nicht 5V tolerant in einer 3V Variante ICM7555 zur VerfĂŒgung.

Arbeitet der Mikrokontroller mit 3,3,V und stehen nur ein NE555 zur VerfĂŒgung, kann natĂŒrlich auch ein Spannungsteiler am Ausgang den Levelshift ĂŒbernehmen.

Der NE555 wird in dieser Schaltung als Multivibrator eingesetzt, der abhÀngig von angeschlossenen Kondensator seine Ausgangsfrequenz verÀndert.

Wenn am Ausgang gleiche Ein- und Ausschaltzeiten erzeugt werden sollen, muss die Standardschaltung (siehe oben) mit einer Diode parallel zum Widerstand R2 aufgebaut werden. Andernfalls kann diese Diode einfach entfallen. In der obigen Bauteilauslegung ist das TastverhÀltnis annÀhernd 1:1 was auch hier die Diode unnötig macht.
Im Programm des Regensensors werden beide Varianten berĂŒcksichtigt. Da sowohl die Zeitdauer der negativen als auch der positive Halbwelle gemessen und anschließend addiert werden. Und damit die ganze Periodendauer berechnet wird.

FĂŒr die Messung wird vom Regensensor nur der Pin 5 (Analogwert) und Pin 7 (GND) benötigt.
Soll die Heizung genutzt werden kommen noch der Pin 1 (VDD) und Pin 3 (Sensorheizung aktivieren) hinzu.

Die Ein- Zeit berechnet sich wie folgt:
T1= 0,694 * (R1 + R2) * C

Die Aus- Zeit berechnet sich wie folgt:
T2= 0,694 * R2 * C

Die gesamte Periodendauer ist die Summe aus T1 +T2
T = 0,694 * C * (R1 +(2 * R2))
f = 1 / T

Die Frequenz ist 1 / T1 + T2, damit ergibt sich die Ausgangsfrequenz nach folgender Formel:
f = 1 / (0,694 * C * (R1 +2 * R2))

Da bei dieser Anwendung fĂŒr uns nicht wichtig ist, welche KapazitĂ€t der Sensor hat, kann bereits die gemessene Frequenz fĂŒr eine Regenauswertung verwendet werden.

Der VollstÀndigkeit halber hier trotzdem noch die kurz die nach C umgestellte Formel:
C =1 / ( f * 0,694 * (R1 + 2 * R2))

Programaufbau fĂŒr die KapazitĂ€tsmessung des Regensensors

/* Capacitivemeasurement (c) by Dillinger-Engineering 10/2020

   Funktionsweise:
   Um die kleinen KapazitÀtsverÀnderungen des Regensensors (pF-Bereich)
   mit einer hohen Genauigkeit zu messen, wird hier ein NE555/3V verwendet.
   Dieser arbeitet als Multivibrator mit einer Frequenz im KHz Bereich.
   Ändert sich die MesskapazitĂ€t, Ă€ndert (sinkt) auch die
   Frequenz. Je nach Auslegeung der Schaltung kann ĂŒber die
   FrequenzÀnderung dann die entsprechende KapazitÀt errechent werden. 
   Je gröer der Parameter "MeasuringCycleleTime" gewÀhlt wird,
   um so genauer wird auch die Messung. Zu beachten ist dabei jedoch,
   dass sich, sollte ein Sensor Fehler (kein Signal vom Eingang) vorliegt, damit
   auch die Timeoutzeit entsprechnde verlÀngert !
*/

const byte InputPin = 5;                       // Wemos D1 mini (Pin D1)
const unsigned int MeasuringCycleleTime = 1e6; // 1000000 us
const long R1 = 10000;   //  10 KOhm
const long R2 = 100000;   // 100 KOhm


float GetFrequeny(){  // Ergebnis in Hz
  float fsum = 0.0;
  unsigned int counts = 0;
  double f, T;
  unsigned long SartTtime = micros();
  bool Fail = false;
  do {
    T = pulseIn(InputPin, HIGH, MeasuringCycleleTime) + pulseIn(InputPin, LOW, MeasuringCycleleTime);
    if(T==0){
      Fail = true;
    }
    f=1/T;      
    counts++;    
    fsum += f * 1e6;
  } while(micros() < (SartTtime + MeasuringCycleleTime) && !Fail); // 1 Sekunde mitteln
  if(Fail){
    return(0);
  }else{
    f = fsum / counts * 0.9925;    //Korrekturwert ermitteln und einrechnen
    return(f);
  }
}

float GetCapacity(){  // Ergebnis in pF
  return(1/(GetFrequeny() * 0.694 * (R1 + 2 * R2))* 1e12);
}

void setup() {
  pinMode(InputPin, INPUT);
  Serial.begin(115200);
}

void loop() {
  char CharStr[30];
  
  // Show Data on Serial if available
  sprintf(CharStr,"Capacity: %.3f pf", GetCapacity()); 
  Serial.println(String(CharStr));
  sprintf(CharStr,"Frequenz: %.3f Hz", GetFrequeny()); 
  Serial.println(String(CharStr));
}